***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 29, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P6SMBJ22A A K 
.param
+ vc0 = 4.046e-13	 vc1 = 1.016e-11	 vc2 = 2.983e-11	 vc3 = 2.255e-1
+ tc1 = 2.478e-2	 tc2 = 1.216e-2		 tc3 = 3.778e-2		 tc4 = 1.716e-2
d1 A K zener
g1 K A value = {(vc0+vc1*v(K,A)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(K,A)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1        
***** dc model parameter *****
+  is = 3.518e-13	   n = 1.107		  rs = 3.965e-2
+ ibv = 1e-3		 nbv = 1		  bv = 25.7
+ ikf = 2
***** capacitance parameter *****
+ cjo = 1.237e-9	   m = 3.314e-1		  vj = 5.063e-1 
+  fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.012		 xti = 3
+trs1 = 4.057e-4	trs2 = 4.057e-6		tbv1 = 6.038e-4		tikf = 1e-3
.ends P6SMBJ22A
*$
